82 lines
2.8 KiB
Zig
82 lines
2.8 KiB
Zig
const std = @import("std");
|
|
|
|
pub fn main() !void {
|
|
var gpa = std.heap.GeneralPurposeAllocator(.{}){};
|
|
const allocator = gpa.allocator();
|
|
|
|
const args = try std.process.argsAlloc(allocator);
|
|
defer std.process.argsFree(allocator, args);
|
|
|
|
if (args.len != 3) return error.InvalidArgs;
|
|
|
|
const kcov_path = args[1];
|
|
const arch_name = args[2];
|
|
|
|
// Check to see if file exists. If it does, we have nothing more to do
|
|
const stat = std.fs.cwd().statFile(kcov_path) catch |err| blk: {
|
|
if (err == error.FileNotFound) break :blk null else return err;
|
|
};
|
|
// This might be better checking whether it's executable and >= 7MB, but
|
|
// for now, we'll do a simple exists check
|
|
if (stat != null) return;
|
|
var stdout_buffer: [1024]u8 = undefined;
|
|
var stdout_writer = std.fs.File.stdout().writer(&stdout_buffer);
|
|
const stdout = &stdout_writer.interface;
|
|
|
|
try stdout.writeAll("Determining latest kcov version\n");
|
|
try stdout.flush();
|
|
|
|
var client = std.http.Client{ .allocator = allocator };
|
|
defer client.deinit();
|
|
|
|
// Get redirect to find latest version
|
|
const list_uri = try std.Uri.parse("https://git.lerch.org/lobo/-/packages/generic/kcov/");
|
|
var req = try client.request(.GET, list_uri, .{ .redirect_behavior = .unhandled });
|
|
defer req.deinit();
|
|
|
|
try req.sendBodiless();
|
|
var redirect_buf: [1024]u8 = undefined;
|
|
const response = try req.receiveHead(&redirect_buf);
|
|
|
|
if (response.head.status != .see_other) return error.UnexpectedResponse;
|
|
|
|
const location = response.head.location orelse return error.NoLocation;
|
|
const version_start = std.mem.lastIndexOf(u8, location, "/") orelse return error.InvalidLocation;
|
|
const version = location[version_start + 1 ..];
|
|
|
|
try stdout.print(
|
|
"Downloading kcov version {s} for {s} to {s}...",
|
|
.{ version, arch_name, kcov_path },
|
|
);
|
|
try stdout.flush();
|
|
|
|
const binary_url = try std.fmt.allocPrint(
|
|
allocator,
|
|
"https://git.lerch.org/api/packages/lobo/generic/kcov/{s}/kcov-{s}",
|
|
.{ version, arch_name },
|
|
);
|
|
defer allocator.free(binary_url);
|
|
|
|
const cache_dir = std.fs.path.dirname(kcov_path) orelse return error.InvalidPath;
|
|
std.fs.cwd().makeDir(cache_dir) catch |e| switch (e) {
|
|
error.PathAlreadyExists => {},
|
|
else => return e,
|
|
};
|
|
|
|
const uri = try std.Uri.parse(binary_url);
|
|
const file = try std.fs.cwd().createFile(kcov_path, .{ .mode = 0o755 });
|
|
defer file.close();
|
|
|
|
var buffer: [8192]u8 = undefined;
|
|
var writer = file.writer(&buffer);
|
|
const result = try client.fetch(.{
|
|
.location = .{ .uri = uri },
|
|
.response_writer = &writer.interface,
|
|
});
|
|
|
|
if (result.status != .ok) return error.DownloadFailed;
|
|
try writer.interface.flush();
|
|
|
|
try stdout.writeAll("done\n");
|
|
try stdout.flush();
|
|
}
|